Multi-User License Deployment on Windows

 Attention — This page presents content from an old edition. Consult the documentation for the current release instead.

Multi-User License Deployment on Windows / 5 - Automated Deployment by GPO / 5 - Updating Antidote / 2 - Updating an Administrative Installation / 2 - Updating the Client Workstation

5.5.2.2 - Updating the Client Workstation

When updating, it is very important to redeploy the MSI file so that the client workstations do not become unsynchronized.

Once the administrative installation is updated, the GPO must be used to redeploy (synchronize) the client workstations’ MSI files using the server’s MSI files. Do so as follows:

msiexec /i "\\path\to\Antidote10.msi" REINSTALL=all REINSTALLMODE=vomus TRANSFORMS="\\path\to\ReseauAntidote.mst"  
msiexec /i "\\path\to\Antidote10-Modulefrancais.msi" REINSTALL=all REINSTALLMODE=vomus  
msiexec /i "\\path\to\Antidote10-Englishmodule.msi" REINSTALL=all REINSTALLMODE=vomus
msiexec /i "\\path\to\Antidote-Connectix10.msi" REINSTALL=all REINSTALLMODE=vomus TRANSFORMS="\\path\to\ReseauConnectix.mst"  
  • The TRANSFORMS does not need to be indicated for the modules.
  • Integration with newly supported software will be completed the next time Antidote 10 is launched (from the Start menu) or the next time each user of the workstation logs in.

For example, here is the content of a script that allows silent updates to a client workstation. Note that there are cookie files, which are necessary to prevent unnecessary reinstallations each time the script is run.

@echo OFF

rem Warning, do not use this script for an initial deployment.

echo Deploying Antidote 10 : synching client / server...

set REMOTE_PATH=\\SERVEUR\DossierAntidote
set LOCAL_PATH=C:\Program Files (x86)\Druide\Antidote 10
mkdir "%LOCAL_PATH%"

if exist "%LOCAL_PATH%\TemoinMajAntidote" goto OK_ANTIDOTE
msiexec /qn /i "%REMOTE_PATH%\Antidote10.msi" TRANSFORMS="%REMOTE_PATH%\ReseauAntidote.mst;%REMOTE_PATH%\Antidote10-Interface-fr.mst" REINSTALL=all REINSTALLMODE=vomus /l*v "%LOCAL_PATH%\logMajAntidote.txt"
echo . > "%LOCAL_PATH%\TemoinMajAntidote"
:OK_ANTIDOTE

if exist "%LOCAL_PATH%\TemoinMajModuleFrancais" goto OK_MODULE_FR
if not exist "%REMOTE_PATH%\Antidote10-Module-francais.msi" goto OK_MODULE_FR
msiexec /qn /i "%REMOTE_PATH%\Antidote10-Module-francais.msi" TRANSFORMS="%REMOTE_PATH%\Antidote10-Module-francais-Interface-fr.mst" REINSTALL=all REINSTALLMODE=vomus /l*v "%LOCAL_PATH%\logMajModuleFr.txt"
echo . > "%LOCAL_PATH%\TemoinMajModuleFrancais"
:OK_MODULE_FR

if exist "%LOCAL_PATH%\TemoinMajEnglishModule" goto OK_MODULE_EN
if not exist "%REMOTE_PATH%\Antidote10-English-module.msi" goto OK_MODULE_EN
msiexec /qn /i "%REMOTE_PATH%\Antidote10-English-module.msi" TRANSFORMS="%REMOTE_PATH%\Antidote10-English-module-Interface-fr.mst" REINSTALL=all REINSTALLMODE=vomus /l*v "%LOCAL_PATH%\logMajModuleEn.txt"
echo . > "%LOCAL_PATH%\TemoinMajEnglishModule"
:OK_MODULE_EN

if exist "%LOCAL_PATH%\TemoinMajConnectix" goto OK_CONNECTIX
if not exist "%REMOTE_PATH%\Antidote-Connectix10.msi" goto OK_CONNECTIX
msiexec /qn /i "%REMOTE_PATH%\Antidote-Connectix10.msi" TRANSFORMS="%REMOTE_PATH%\ReseauConnectix.mst;%REMOTE_PATH%\Antidote-Connectix10-Interface-fr.mst" REINSTALL=all REINSTALLMODE=vomus /l*v "%LOCAL_PATH%\logMajConnectix.txt"
echo . > "%LOCAL_PATH%\TemoinMajConnectix"
:OK_CONNECTIX