Multi-User License Deployment on Windows

 Attention — This page presents content from an old edition. Consult the documentation for the current release instead.

Multi-User License Deployment on Windows / 5 - Automated Deployment by GPO / 3 - Installing Antidote 10 / Method 2 - Deploying an Administrative Installation / 2 - Installation on the Client Workstation

5.3.2.2 - Installation on the Client Workstation

Deployment of the client portion involves using GPO to deploy a script rather than the MSI installers directly. This script will deploy the 3 or 4 reduced-size MSI files created during the previous step in the correct order.

  • In the installation sequence, Antidote10.msi must be launched first: the Antidote 10 application must be installed before the language modules. Since the deployment of MSI by GPO does not ensure the correct order, deployment must be performed using an installation script.
  • In the GPO interface, assign the script to a machine, not to a user.
  • The script must be deployed at the same time that the workstation is opened. Thus, depending on your version of Windows Server, the following two commands must be activated:
    Computer Configuration\Administrative Templates\System\Logon (ou Scripts) Run logon scripts synchronously = Enabled
    AND
    Computer Configuration\Administrative Templates\System\Logon (ou Scripts) Run logon scripts asynchronously = Disabled

For example, here is the content of a script that allows initial silent installation of Antidote. Note that there are cookie files, which are necessary to prevent unnecessary installations each time the script is run:

@echo OFF
rem Warning, this script is encoded page DOS-850

echo Deploying Antidote 10...

set REMOTE_PATH=\\SERVEUR\DossierAntidote
set LOCAL_PATH=C:\Program Files (x86)\Druide\Antidote 10
mkdir "%LOCAL_PATH%"

if exist "%LOCAL_PATH%\TemoinInsAntidote" goto OK_ANTIDOTE
msiexec /qn /i "%REMOTE_PATH%\Antidote10.msi" TRANSFORMS="%REMOTE_PATH%\ReseauAntidote.mst;%REMOTE_PATH%\Antidote10-Interface-fr.mst" /l*v "%LOCAL_PATH%\logInsAntidote.txt"
echo . > "%LOCAL_PATH%\TemoinInsAntidote"
:OK_ANTIDOTE

if exist "%LOCAL_PATH%\TemoinInsModuleFrancais" goto OK_MODULE_FR
if not exist "%REMOTE_PATH%\Antidote10-Module-francais.msi" goto OK_MODULE_FR
msiexec /qn /i "%REMOTE_PATH%\Antidote10-Module-francais.msi" TRANSFORMS="%REMOTE_PATH%\Antidote10-Module-francais-Interface-fr.mst" /l*v "%LOCAL_PATH%\logInsModuleFr.txt"
echo . > "%LOCAL_PATH%\TemoinInsModuleFrancais"
:OK_MODULE_FR

if exist "%LOCAL_PATH%\TemoinInsEnglishModule" goto OK_MODULE_EN
if not exist "%REMOTE_PATH%\Antidote10-English-module.msi" goto OK_MODULE_EN
msiexec /qn /i "%REMOTE_PATH%\Antidote10-English-module.msi" TRANSFORMS="%REMOTE_PATH%\Antidote10-English-module-Interface-fr.mst" /l*v "%LOCAL_PATH%\logInsModuleEn.txt"
echo . > "%LOCAL_PATH%\TemoinInsEnglishModule"
:OK_MODULE_EN

if exist "%LOCAL_PATH%\TemoinInsConnectix" goto OK_CONNECTIX
if not exist "%REMOTE_PATH%\Antidote-Connectix10.msi" goto OK_CONNECTIX
msiexec /qn /i "%REMOTE_PATH%\Antidote-Connectix10.msi" TRANSFORMS="%REMOTE_PATH%\ReseauConnectix.mst;%REMOTE_PATH%\Antidote-Connectix10-Interface-fr.mst" /l*v "%LOCAL_PATH%\logInsConnectix.txt"
echo . > "%LOCAL_PATH%\TemoinInsConnectix"
:OK_CONNECTIX
An error has occurred. Please try again later.