Antidote 10 — Installation multiposte Windows

 Attention — Cette page présente le contenu d’une ancienne édition. Consultez plutôt la documentation de l’édition courante.

Installation multiposte Windows / 6 - Autres outils de déploiement automatisé / 2 - Exemples de scripts / B - Exemple de script pour un déploiement initial

6.2.B - Exemple de script pour un déploiement initial

@echo OFF
rem Attention ce fichier est encod‚ en code page DOS-850

echo D‚ploiement d’Antidote 10...

set CHEMIN_SERVEUR=\\SERVEUR\DossierAntidote
set CHEMIN_LOCAL=C:\Program Files (x86)\Druide\Antidote 10
mkdir "%CHEMIN_LOCAL%"

if exist "%CHEMIN_LOCAL%\TemoinDesAnciensAntidote" goto OK_DESANCIENANTIDOTE
rem A6 (Antidote RX)
msiexec /qn /x {A474EA56-5DBD-4181-8230-806A4762EA7F} /l*v "%CHEMIN_LOCAL%\logDesAncienAntidoteA6.txt"
rem A7 (Antidote HD)
msiexec /qn /x {56CDB4FE-895F-4E0D-8BB4-9A8D4310898D} /l*v "%CHEMIN_LOCAL%\logDesAncienAntidoteA7.txt"
rem A8 (Antidote 8)
msiexec /qn /x {09AAAB09-6DBA-4DD9-9865-54597D3FBCA8} /l*v "%CHEMIN_LOCAL%\logDesAncienAntidoteA8.txt"
rem A9 (Antidote 10)
msiexec /qn /x {BFA17B4C-70D3-480F-8476-76197F614AB6} /l*v "%CHEMIN_LOCAL%\logDesAncienAntidoteA9.txt"
msiexec /qn /x {BFA17B4C-70D3-480F-8476-76197F614AB7} /l*v "%CHEMIN_LOCAL%\logDesAncienAntidoteA9_FR.txt"
msiexec /qn /x {BFA17B4C-70D3-480F-8476-76197F614AB8} /l*v "%CHEMIN_LOCAL%\logDesAncienAntidoteA9_EN.txt"
echo . > "%CHEMIN_LOCAL%\TemoinDesAnciensAntidote"
:OK_DESANCIENANTIDOTE

if exist "%CHEMIN_LOCAL%\TemoinInsAntidote" goto OK_ANTIDOTE
msiexec /qn /i "%CHEMIN_SERVEUR%\Antidote10.msi" TRANSFORMS="%CHEMIN_SERVEUR%\ReseauAntidote.mst;%CHEMIN_SERVEUR%\Antidote10-Interface-fr.mst" /l*v "%CHEMIN_LOCAL%\logInsAntidote.txt"
echo . > "%CHEMIN_LOCAL%\TemoinInsAntidote"
:OK_ANTIDOTE

if exist "%CHEMIN_LOCAL%\TemoinInsModuleFrancais" goto OK_MODULE_FR
if not exist "%CHEMIN_SERVEUR%\Antidote10-Module-francais.msi" goto OK_MODULE_FR
msiexec /qn /i "%CHEMIN_SERVEUR%\Antidote10-Module-francais.msi" TRANSFORMS="%CHEMIN_SERVEUR%\Antidote10-Module-francais-Interface-fr.mst" /l*v "%CHEMIN_LOCAL%\logInsModuleFr.txt"
echo . > "%CHEMIN_LOCAL%\TemoinInsModuleFrancais"
:OK_MODULE_FR

if exist "%CHEMIN_LOCAL%\TemoinInsEnglishModule" goto OK_MODULE_EN
if not exist "%CHEMIN_SERVEUR%\Antidote10-English-module.msi" goto OK_MODULE_EN
msiexec /qn /i "%CHEMIN_SERVEUR%\Antidote10-English-module.msi" TRANSFORMS="%CHEMIN_SERVEUR%\Antidote10-English-module-Interface-fr.mst" /l*v "%CHEMIN_LOCAL%\logInsModuleEn.txt"
echo . > "%CHEMIN_LOCAL%\TemoinInsEnglishModule"
:OK_MODULE_EN

if exist "%CHEMIN_LOCAL%\TemoinInsConnectix" goto OK_CONNECTIX
if not exist "%CHEMIN_SERVEUR%\Antidote-Connectix10.msi" goto OK_CONNECTIX
msiexec /qn /i "%CHEMIN_SERVEUR%\Antidote-Connectix10.msi" TRANSFORMS="%CHEMIN_SERVEUR%\ReseauConnectix.mst;%CHEMIN_SERVEUR%\Antidote-Connectix10-Interface-fr.mst" /l*v "%CHEMIN_LOCAL%\logInsConnectix.txt"
echo . > "%CHEMIN_LOCAL%\TemoinInsConnectix"
:OK_CONNECTIX
Une erreur est survenue. Veuillez réessayer plus tard.