Déploiement en organisation

Déploiement en organisation / Installation des logiciels par l’administrateur / Déploiement automatisé sur plusieurs postes / Déploiement automatisé par GPO / Installation

Installation

Le déploiement d’une installation d’Antidote 12 par GPO nécessite de créer les fichiers ReseauAntidote.mst et ReseauConnectix.mst à l’aide de l’utilitaire GestionnaireDeDeploiement_Antidote12.exe, qui peut être téléchargée depuis l’Espace client de votre organisation. C’est également dans votre Espace client que vous pouvez télécharger les installateurs complets d’Antidote 12 associés à votre licence ou abonnement. Dans le cas d’une installation bilingue, ce sera le fichier Antidote_12.x_B_x_Windows.exe, une archive exécutable contenant les installateurs des applications Antidote 12 et Connectix 12 ainsi que ceux des modules français et anglais d’Antidote 12. Au début de la configuration, le Gestionnaire de déploiement vous demandera de lui indiquer l’emplacement des installateurs Antidote12.msi et Antidote-Connectix12.msi : il en aura besoin pour créer les fichiers de transformation ReseauAntidote.mst et ReseauConnectix.mst.

  1. Entrez dans un compte administrateur.

  2. Téléchargez, depuis l’Espace client de votre organisation, l’installateur complet (Antidote_12.y_B_n_Windows.exe) et le Gestionnaire de déploiement (GestionnaireDeDeploiement_Antidote12.exe).

    Lorsqu’une mise à jour d’Antidote est publiée, l’installateur complet d’Antidote correspondant à la version de cette mise à jour sera disponible dans l’Espace client de votre organisation.

  3. Assurez-vous que les préalables sont respectés.

  4. Exécutez l’installateur Antidote_12.y_B_n_Windows.exe.

  5. Choisissez « Extraire » pour décompresser un dossier de la forme Antidote_12.y_B_n_Installation contenant les fichiers d’installation.

  6. Créez les fichiers ReseauAntidote.mst et ReseauConnectix.mst à l’aide du Gestionnaire de déploiement, qui vous demandera de lui indiquer l’emplacement des installateurs Antidote12.msi et Antidote-Connectix12.msi. À la dernière étape de la configuration, spécifiez le dossier msi\druide qui contient déjà les installateurs Antidote12.msi et Antidote-Connectix12.msi afin qu’y soient générés les fichiers MST. Pour plus de détails sur cet utilitaire, voir Configuration et activation.

  7. Placez tous les fichiers nécessaires sur le serveur (ou un disque accessible). Par exemple, pour une installation bilingue :

    Antidote12.msi
    Antidote12-Module-francais.msi
    Antidote12-English-module.msi
    Antidote-Connectix12.msi
    ReseauAntidote.mst (créé précédemment)
    ReseauConnectix.mst (créé précédemment)

    Si vous voulez modifier la langue prévue pour les dialogues de l’installateur, pour que ceux-ci soient en français, il faut aussi utiliser les fichiers MST qui s’appliquent et qui se trouvent dans le dossier msi\druide, par exemple : Antidote12-Interface-fr.mst pour l’installateur d’Antidote 12, Antidote-Connectix12-Interface-fr.mst pour l’installateur de Connectix 12, Antidote12-English-module-Interface-fr.mst pour l’installateur du Module Anglais et Antidote12-Module-francais-Interface-fr.mst pour l’installateur du Module Français. Voir plus loin comment les ajouter à la ligne de commande.

    Dans la séquence d’installation, il est essentiel que le fichier Antidote12.msi soit lancé en premier : l’installation de l’application Antidote 12 doit être effectuée avant l’installation des modules de langue.

  8. Utilisez GPO pour déployer un script plutôt que les installateurs MSI directement. Ce script doit déployer les trois ou quatre MSI dans l’ordre approprié.

    • GPO ne permet pas de garantir l’ordre d’installation, il est nécessaire de réaliser le déploiement à l’aide d’un script d’installation.
    • Dans l’interface de GPO, assignez le script à une machine, et non à un utilisateur.
    • Le script doit être déployé de façon synchrone au démarrage du poste. Ainsi, selon votre version de Windows Server, les deux politiques suivantes doivent être activées :
      Computer Configuration\Administrative Templates\System\Logon (ou Scripts)
      Run logon scripts synchronously = Enabled
      ET
      Computer Configuration\Administrative Templates\System\Logon (ou Scripts)
      Run logon scripts asynchronously = Disabled

    L’utilisation du Gestionnaire de déploiement (voir Configuration et activation) est essentielle pour permettre une installation silencieuse.

Voici un exemple complet d’un script d’installation silencieuse.

Dans cet exemple, la présence des fichiers d’Antidote 12 et de Connectix est vérifiée afin d’éviter une installation inutile à chaque exécution du script.

@echo OFF
rem Attention ce fichier est encodé en code page DOS-850

echo Déploiement d'Antidote 12...

set CHEMIN_SERVEUR=\\SERVEUR\DossierAntidote
set CHEMIN_LOCAL=C:\Program Files\Druide
set CHEMIN_ANTIDOTE=%CHEMIN_LOCAL%\Antidote 12
set CHEMIN_CONNECTIX=%CHEMIN_LOCAL%\Connectix 12
set CHEMIN_LOG=%PROGRAMDATA%\Druide

mkdir "%CHEMIN_LOG%"

if exist "%CHEMIN_ANTIDOTE%\Application\Bin64\Antidote.exe" goto OK_DESANCIENANTIDOTE
if exist "%CHEMIN_CONNECTIX%\Application\Bin64\Connectix.exe" goto OK_DESANCIENANTIDOTE
rem A6 (Antidote RX)
msiexec /qn /x {A474EA56-5DBD-4181-8230-806A4762EA7F} /l*v "%CHEMIN_LOG%\logDesAntidoteRX.txt"
rem A7 (Antidote HD)
msiexec /qn /x {56CDB4FE-895F-4E0D-8BB4-9A8D4310898D} /l*v "%CHEMIN_LOG%\logDesAntidoteHD.txt"
rem A8 (Antidote 8)
msiexec /qn /x {09AAAB09-6DBA-4DD9-9865-54597D3FBCA8} /l*v "%CHEMIN_LOG%\logDesAntidote8.txt"
rem A9 (Antidote 9)
msiexec /qn /x {BFA17B4C-70D3-480F-8476-76197F614AB6} /l*v "%CHEMIN_LOG%\logDesAntidote9.txt"
msiexec /qn /x {BFA17B4C-70D3-480F-8476-76197F614AB7} /l*v "%CHEMIN_LOG%\logDesAntidote9_Module_Français.txt"
msiexec /qn /x {BFA17B4C-70D3-480F-8476-76197F614AB8} /l*v "%CHEMIN_LOG%\logDesAntidote9_English_Module.txt"
rem A10 (Antidote 10)
msiexec /qn /x {134E0741-C569-4E8C-A7FC-7F95B14CAAB1} /l*v "%CHEMIN_LOG%\logDesAntidote10.txt"
msiexec /qn /x {134E0741-C569-4E8C-A7FC-7F95B14CAAB2} /l*v "%CHEMIN_LOG%\logDesAntidote10_Module_Français.txt"
msiexec /qn /x {134E0741-C569-4E8C-A7FC-7F95B14CAAB3} /l*v "%CHEMIN_LOG%\logDesAntidote10_English_Module.txt"
msiexec /qn /x {134E0741-C569-4E8C-A7FC-7F95B14CAAB4} /l*v "%CHEMIN_LOG%\logDesAntidote10_Connectix.txt"
rem A11 (Antidote 11)
msiexec /qn /x {2643823D-D15F-4046-8388-401756A5C921} /l*v "%CHEMIN_LOG%\logDesAntidote11.txt"
msiexec /qn /x {2643823D-D15F-4046-8388-401756A5C922} /l*v "%CHEMIN_LOG%\logDesAntidote11_Module_Français.txt"
msiexec /qn /x {2643823D-D15F-4046-8388-401756A5C923} /l*v "%CHEMIN_LOG%\logDesAntidote11_English_Module.txt"
msiexec /qn /x {2643823D-D15F-4046-8388-401756A5C924} /l*v "%CHEMIN_LOG%\logDesAntidote11_Connectix.txt"
:OK_DESANCIENANTIDOTE

if exist "%CHEMIN_ANTIDOTE%\Application\Bin64\Antidote.exe" goto OK_ANTIDOTE
if not exist "%CHEMIN_SERVEUR%\Antidote12.msi" goto OK_ANTIDOTE
msiexec /qn /i "%CHEMIN_SERVEUR%\Antidote12.msi" TRANSFORMS="%CHEMIN_SERVEUR%\ReseauAntidote.mst;%CHEMIN_SERVEUR%\Antidote12-Interface-fr.mst" /l*v "%CHEMIN_LOG%\logInsAntidote12.txt"
:OK_ANTIDOTE

if exist "%CHEMIN_ANTIDOTE%\LingFR\Bin64\libLingFR.dll" goto OK_MODULE_FR
if not exist "%CHEMIN_SERVEUR%\Antidote12-Module-francais.msi" goto OK_MODULE_FR
msiexec /qn /i "%CHEMIN_SERVEUR%\Antidote12-Module-francais.msi" TRANSFORMS="%CHEMIN_SERVEUR%\Antidote12-Module-francais-Interface-fr.mst" /l*v "%CHEMIN_LOG%\logInsAntidote12_Module_Français.txt"
:OK_MODULE_FR

if exist "%CHEMIN_ANTIDOTE%\LingEN\Bin64\libLingEN.dll" goto OK_MODULE_EN
if not exist "%CHEMIN_SERVEUR%\Antidote12-English-module.msi" goto OK_MODULE_EN
msiexec /qn /i "%CHEMIN_SERVEUR%\Antidote12-English-module.msi" TRANSFORMS="%CHEMIN_SERVEUR%\Antidote12-English-module-Interface-fr.mst" /l*v "%CHEMIN_LOG%\logInsAntidote12_English_Module.txt"
:OK_MODULE_EN

if exist "%CHEMIN_CONNECTIX%\Application\Bin64\Connectix.exe" goto OK_CONNECTIX
if not exist "%CHEMIN_SERVEUR%\Antidote-Connectix12.msi" goto OK_CONNECTIX
msiexec /qn /i "%CHEMIN_SERVEUR%\Antidote-Connectix12.msi" TRANSFORMS="%CHEMIN_SERVEUR%\ReseauConnectix.mst;%CHEMIN_SERVEUR%\Antidote-Connectix12-Interface-fr.mst" /l*v "%CHEMIN_LOG%\logInsAntidote12_Connectix.txt"
:OK_CONNECTIX