Multi-User License Deployment on Windows

Multi-User License Deployment on Windows / 5 - Automated Deployment by GPO / 3 - Installing Antidote 11 / Method 1 - Installing Antidote 11 by Command Line

Method 1 - Installing Antidote 11 by Command Line

Local installation with the command line is one of the methods of deployment by GPO. It involves the following:

  1. Log in as an administrator.
  2. Download the following file types from your Multi-User Client Portal: Antidote_11.y_B_n_Windows.exe and GestionnaireMultiposte_Antidote11.exe.
  3. Ensure that the conditions are met.
  4. Execute the main archive, which takes the following form: Antidote_11.y_B_n_Windows.exe. This will extract a folder containing the installation files onto the desktop. This folder takes the following form: Antidote_11.y_B_n_Installation.
  5. Create the ReseauAntidote.mst and ReseauConnectix.MST files using the Multi-User Manager, which will ask you to indicate the Antidote11.msi and Antidote-Connectix11.msi files. See Appendix A: Multi-User Manager.
  6. Place all of the necessary files on the server (or an accessible drive), as well as all of the MSP updates, if applicable (if any updates have been published more recently than your installers). See the following example (bilingual installation):

    Antidote11.msi
    Antidote11-Module-francais.msi
    Antidote11-English-module.msi
    Antidote-Connectix11.msi
    ReseauAntidote.mst (created previously)
    ReseauConnectix.mst (created previously)
    There may be a published MSP update for each of these elements: one for Antidote 11, one for Antidote - Connectix 11, one for the French module and one for the English module. In addition, there may be an MSP update for the connectors, which are extensions or modules installed in supported software. A single connectors update may be for multiple software applications. This type of update is published between updates to Antidote so that our application can rapidly adapt to changes in supported software. Note that this may be the only type of update you receive.

    If you want the installer’s dialogues to be in English, you must also use the applicable MST files, which are found in the folder msi\druide. For example, Antidote11-Interface-en.mst for the Antidote 11 installer, Antidote-Connectix11-Interface-en.mst for the Antidote - Connectix 11 installer, Antidote11-English-module-Interface-en.mst for the English module installer and Antidote11-Module-francais-Interface-en.mst for the French module installer. Read on for information on adding these to the command line.

    When an update to Antidote is published, the complete installer for this version of the update is usually released within the next few days. As soon as the installer is published, it appears in your Multi-User Client Portal provided you have subscribed to the Antidote Maintenance Program (AMP). Otherwise, the same outcome can be achieved by installing Antidote with the initial installers, accessible from your Multi-User Client Portal, and then applying the latest updates.

    In the installation sequence, it is essential that you launch the Antidote11.msi file first. The Antidote 11 application must be installed before the language modules.

  1. Use GPO to deploy a script. Do not use the MSI installers directly. This script will deploy the 3 or 4 MSI files in the correct order.

    • GPO does not guarantee the order of installation. Deployment must be carried out using an installation script. For an example script, see Using scripts.
    • In the GPO interface, assign the script to a machine, not a user.
    • The script must be deployed at the same time that the workstation is opened. Thus, depending on your version of Windows Server, the following two commands must be activated:
      Computer Configuration\Administrative Templates\System\Logon (ou Scripts)
      Run logon scripts synchronously = Enabled
      AND
      Computer Configuration\Administrative Templates\System\Logon (ou Scripts)
      Run logon scripts asynchronously = Disabled

    Using the Multi-User Manager (see Appendix A: Multi-User Manager) is essential for silent installation.

For example, here is the content of a script that allows the initial silent installation of Antidote. Note that there are cookie files, which are necessary to prevent unnecessary installations each time the script is run.

@echo OFF
rem Warning, this script is encode page DOS-850

echo Deploying Antidote 11...

set REMOTE_PATH=\\SERVEUR\DossierAntidote
set LOCAL_PATH=C:\Program Files (x86)\Druide\Antidote 11
mkdir "%LOCAL_PATH%"

if exist "%LOCAL_PATH%\TemoinDesAnciensAntidote" goto OK_DESANCIENANTIDOTE
rem A6 (Antidote RX)
msiexec /qn /x {A474EA56-5DBD-4181-8230-806A4762EA7F} /l*v "%LOCAL_PATH%\logDesAncienAntidoteA6.txt"
rem A7 (Antidote HD)
msiexec /qn /x {56CDB4FE-895F-4E0D-8BB4-9A8D4310898D} /l*v "%LOCAL_PATH%\logDesAncienAntidoteA7.txt"
rem A8 (Antidote 8)
msiexec /qn /x {09AAAB09-6DBA-4DD9-9865-54597D3FBCA8} /l*v "%LOCAL_PATH%\logDesAncienAntidoteA8.txt"
rem A9 (Antidote 9)
msiexec /qn /x {BFA17B4C-70D3-480F-8476-76197F614AB6} /l*v "%LOCAL_PATH%\logDesAncienAntidoteA9.txt"
msiexec /qn /x {BFA17B4C-70D3-480F-8476-76197F614AB7} /l*v "%LOCAL_PATH%\logDesAncienAntidoteA9_FR.txt"
msiexec /qn /x {BFA17B4C-70D3-480F-8476-76197F614AB8} /l*v "%LOCAL_PATH%\logDesAncienAntidoteA9_EN.txt"
rem A10 (Antidote 10)
msiexec /qn /x {134E0741-C569-4E8C-A7FC-7F95B14CAAB1} /l*v "%CHEMIN_LOCAL%\logDesAncienAntidoteA10.txt"
msiexec /qn /x {134E0741-C569-4E8C-A7FC-7F95B14CAAB2} /l*v "%CHEMIN_LOCAL%\logDesAncienAntidoteA10_FR.txt"
msiexec /qn /x {134E0741-C569-4E8C-A7FC-7F95B14CAAB3} /l*v "%CHEMIN_LOCAL%\logDesAncienAntidoteA10_EN.txt"
msiexec /qn /x {134E0741-C569-4E8C-A7FC-7F95B14CAAB4} /l*v "%CHEMIN_LOCAL%\logDesAncienAntidoteA10_CNX.txt"
echo . > "%LOCAL_PATH%\TemoinDesAnciensAntidote"
:OK_DESANCIENANTIDOTE

if exist "%LOCAL_PATH%\TemoinInsAntidote" goto OK_ANTIDOTE
msiexec /qn /i "%REMOTE_PATH%\Antidote11.msi" TRANSFORMS="%REMOTE_PATH%\ReseauAntidote.mst;%REMOTE_PATH%\Antidote11-Interface-fr.mst" /l*v "%LOCAL_PATH%\logInsAntidote.txt"
echo . > "%LOCAL_PATH%\TemoinInsAntidote"
:OK_ANTIDOTE

if exist "%LOCAL_PATH%\TemoinInsModuleFrancais" goto OK_MODULE_FR
if not exist "%REMOTE_PATH%\Antidote11-Module-francais.msi" goto OK_MODULE_FR
msiexec /qn /i "%REMOTE_PATH%\Antidote11-Module-francais.msi" TRANSFORMS="%REMOTE_PATH%\Antidote11-Module-francais-Interface-fr.mst" /l*v "%LOCAL_PATH%\logInsModuleFr.txt"
echo . > "%LOCAL_PATH%\TemoinInsModuleFrancais"
:OK_MODULE_FR

if exist "%LOCAL_PATH%\TemoinInsEnglishModule" goto OK_MODULE_EN
if not exist "%REMOTE_PATH%\Antidote11-English-module.msi" goto OK_MODULE_EN
msiexec /qn /i "%REMOTE_PATH%\Antidote11-English-module.msi" TRANSFORMS="%REMOTE_PATH%\Antidote11-English-module-Interface-fr.mst" /l*v "%LOCAL_PATH%\logInsModuleEn.txt"
echo . > "%LOCAL_PATH%\TemoinInsEnglishModule"
:OK_MODULE_EN

if exist "%LOCAL_PATH%\TemoinInsConnectix" goto OK_CONNECTIX
if not exist "%REMOTE_PATH%\Antidote-Connectix11.msi" goto OK_CONNECTIX
msiexec /qn /i "%REMOTE_PATH%\Antidote-Connectix11.msi" TRANSFORMS="%REMOTE_PATH%\ReseauConnectix.mst;%REMOTE_PATH%\Antidote-Connectix11-Interface-fr.mst" /l*v "%LOCAL_PATH%\logInsConnectix.txt"
echo . > "%LOCAL_PATH%\TemoinInsConnectix"
:OK_CONNECTIX
An error has occurred. Please try again later.