Deployment in an Organization

Deployment in an Organization / Installing the Software—Administrators / Automated Deployment on Multiple Devices / Automated Deployment by GPO / Updating

Updating

Updating Antidote is done by reinstalling using more recent installers.

  1. Log in as an administrator.

  2. Download the complete installer (Antidote_12.y_B_n_Windows.exe) from your Organization Client Portal.

  3. Ensure that the prerequisites are met.

  4. Run the installer Antidote_12.y_B_n_Windows.exe.

  5. Select Extract to unzip a folder that contains the installation files and takes the following form: Antidote_12.y_B_n_Installation.

  6. Place all of the necessary files on the server (or an accessible drive). See the following example (bilingual installation):

    Antidote12.msi
    Antidote12-Module-francais.msi
    Antidote12-English-module.msi
    Antidote-Connectix12.msi

    In the installation sequence, it is essential that you launch the Antidote12.msi file first. The Antidote 12 application must be installed before the language modules.

  7. Use GPO to deploy a script. Do not use the MSI installers directly. This script must deploy the 3 or 4 MSI files in the correct order.

    • GPO does not guarantee the order of installation. Deployment must be carried out using an installation script.
    • In the GPO interface, assign the script to a machine, not a user.
    • The script must be deployed at boot, but before user login. Thus, depending on your version of Windows Server, the following two commands must be activated:
      Computer Configuration\Administrative Templates\System\Logon (ou Scripts)
      Run logon scripts synchronously = Enabled
      AND
      Computer Configuration\Administrative Templates\System\Logon (ou Scripts)
      Run logon scripts asynchronously = Disabled

Here is a complete example of a silent update script.

In this example, the existence of Antidote 12 and Connectix files is verified to only attempt to update existing installations.

@echo OFF
rem Warning, this file is encoded in DOS-850

rem Warning, do not use this script for an initial deployment.

echo Updating Antidote 12...

set REMOTE_PATH=\\SERVER\AntidoteFolder
set LOCAL_PATH=C:\Program Files\Druide
set ANTIDOTE_PATH=%LOCAL_PATH%\Antidote 12
set CONNECTIX_PATH=%LOCAL_PATH%\Connectix 12
set LOG_PATH=%PROGRAMDATA%\Druide

mkdir "%LOG_PATH%"

if not exist "%ANTIDOTE_PATH%\Application\Bin64\Antidote.exe" goto OK_ANTIDOTE
if not exist "%REMOTE_PATH%\Antidote12.msi" goto OK_ANTIDOTE
msiexec /qn REINSTALL=ALL REINSTALLMODE=vomus /i "%REMOTE_PATH%\Antidote12.msi" TRANSFORMS="%REMOTE_PATH%\ReseauAntidote.mst;%REMOTE_PATH%\Antidote12-Interface-fr.mst" /l*v "%LOCAL_PATH%\logMajAntidote12.txt"
:OK_ANTIDOTE

if not exist "%ANTIDOTE_PATH%\LingFR\Bin64\libLingFR.dll" goto OK_MODULE_FR
if not exist "%REMOTE_PATH%\Antidote12-Module-francais.msi" goto OK_MODULE_FR
msiexec /qn REINSTALL=ALL REINSTALLMODE=vomus /i "%REMOTE_PATH%\Antidote12-Module-francais.msi" TRANSFORMS="%REMOTE_PATH%\Antidote12-Module-francais-Interface-fr.mst" /l*v "%LOCAL_PATH%\logMajAntidote12_Module_Français.txt"
:OK_MODULE_FR

if not exist "%ANTIDOTE_PATH%\LingEN\Bin64\libLingEN.dll" goto OK_MODULE_EN
if not exist "%REMOTE_PATH%\Antidote12-English-module.msi" goto OK_MODULE_EN
msiexec /qn REINSTALL=ALL REINSTALLMODE=vomus /i "%REMOTE_PATH%\Antidote12-English-module.msi" TRANSFORMS="%REMOTE_PATH%\Antidote12-English-module-Interface-fr.mst" /l*v "%LOCAL_PATH%\logMajAntidote12_English_Module.txt"
:OK_MODULE_EN

if not exist "%CONNECTIX_PATH%\Application\Bin64\Connectix.exe" goto OK_CONNECTIX
if not exist "%REMOTE_PATH%\Antidote-Connectix12.msi" goto OK_CONNECTIX
msiexec /qn REINSTALL=ALL REINSTALLMODE=vomus /i "%REMOTE_PATH%\Antidote-Connectix12.msi" TRANSFORMS="%REMOTE_PATH%\ReseauConnectix.mst;%REMOTE_PATH%\Antidote-Connectix12-Interface-fr.mst" /l*v "%LOCAL_PATH%\logMajAntidote12_Connectix.txt"
:OK_CONNECTIX