Installing

The deployment of Antidote 12 by GPO requires the creation of the ReseauAntidote.mst and ReseauConnectix.mst files using the GestionnaireDeDeploiement_Antidote12.exe utility. This utility can be downloaded from your Organization Client Portal, where you can also download the Antidote 12 installers linked to your license or subscription. In the case of a bilingual installation, it will be the file Antidote_12.x_B_x_Windows.exe, a self-extracting archive containing the installers for the Antidote 12 and Connectix 12 applications and for the French and English modules. When first configuring using the Deployment Manager, you will be asked to indicate where the Antidote12.msi and Antidote-Connectix12.msi installers are located; they are necessary to create the ReseauAntidote.mst and ReseauConnectix.mst transformation files.

Log in as an administrator.
Download the complete installer (Antidote_12.y_B_n_Windows.exe) and the Deployment Manager (GestionnaireDeDeploiement_Antidote12.exe) from your Organization Client Portal.

When an Antidote update is issued, the complete Antidote installer for the version of this update will be available in your Organization Client Portal.
Ensure that the prerequisites are met.
Run the installer Antidote_12.y_B_n_Windows.exe.
Select Extract to unzip a folder that contains the installation files and takes the following form: Antidote_12.y_B_n_Installation.
Create the files ReseauAntidote.mst and ReseauConnectix.mst with the Deployment Manager. You will be asked where the installers Antidote12.msi and Antidote-Connectix12.msi are located. During the last configuration step, specify the folder msi\druide which already has the installers Antidote12.msi and Antidote-Connectix12.msi in order to generate the MST files there. To learn more about this utility, see Configuring and activating.
Place all of the necessary files on the server (or an accessible drive). See the following example (bilingual installation):

Antidote12.msi
Antidote12-Module-francais.msi
Antidote12-English-module.msi
Antidote-Connectix12.msi
ReseauAntidote.mst (created previously)
ReseauConnectix.mst (created previously)

If you want the installer’s dialogues to be in English, you must also use the applicable MST files, which are found in the folder msi\druide. For example, Antidote12-Interface-en.mst for the Antidote 12 installer, Antidote-Connectix12-Interface-en.mst for the Connectix 12 installer, Antidote12-English-module-Interface-en.mst for the English module installer and Antidote12-Module-francais-Interface-en.mst for the French module installer. Read on for information on adding these to the command line.

In the installation sequence, it is essential that you launch the Antidote12.msi file first. The Antidote 12 application must be installed before the language modules.
Use GPO to deploy a script. Do not use the MSI installers directly. This script must deploy the 3 or 4 MSI files in the correct order.
- GPO does not guarantee the order of installation. Deployment must be carried out using an installation script.
- In the GPO interface, assign the script to a machine, not a user.
- The script must be deployed at boot, but before user login. Thus, depending on your version of Windows Server, the following two commands must be activated:
  Computer Configuration\Administrative Templates\System\Logon (ou Scripts)
  Run logon scripts synchronously = Enabled
  AND
  Computer Configuration\Administrative Templates\System\Logon (ou Scripts)
  Run logon scripts asynchronously = Disabled
Using the Deployment Manager (see Configuring and activating) is essential for silent installation.

Here is a complete example of a silent installation script.

In this example, the existence of Antidote 12 and Connectix files is verified to prevent unnecessary installs each time the script is run.

@echo OFF
rem Warning, this file is encoded in DOS-850

echo Deploying Antidote 12...

set REMOTE_PATH=\\SERVER\AntidoteFolder
set LOCAL_PATH=C:\Program Files\Druide
set ANTIDOTE_PATH=%LOCAL_PATH%\Antidote 12
set CONNECTIX_PATH=%LOCAL_PATH%\Connectix 12
set LOG_PATH=%PROGRAMDATA%\Druide

mkdir "%LOG_PATH%"

if exist "%ANTIDOTE_PATH%\Application\Bin64\Antidote.exe" goto OK_DESANCIENANTIDOTE
if exist "%CONNECTIX_PATH%\Application\Bin64\Connectix.exe" goto OK_DESANCIENANTIDOTE
rem A6 (Antidote RX)
msiexec /qn /x {A474EA56-5DBD-4181-8230-806A4762EA7F} /l*v "%LOG_PATH%\logDesAntidoteRX.txt"
rem A7 (Antidote HD)
msiexec /qn /x {56CDB4FE-895F-4E0D-8BB4-9A8D4310898D} /l*v "%LOG_PATH%\logDesAntidoteHD.txt"
rem A8 (Antidote 8)
msiexec /qn /x {09AAAB09-6DBA-4DD9-9865-54597D3FBCA8} /l*v "%LOG_PATH%\logDesAntidote8.txt"
rem A9 (Antidote 9)
msiexec /qn /x {BFA17B4C-70D3-480F-8476-76197F614AB6} /l*v "%LOG_PATH%\logDesAntidote9.txt"
msiexec /qn /x {BFA17B4C-70D3-480F-8476-76197F614AB7} /l*v "%LOG_PATH%\logDesAntidote9_Module_Français.txt"
msiexec /qn /x {BFA17B4C-70D3-480F-8476-76197F614AB8} /l*v "%LOG_PATH%\logDesAntidote9_English_Module.txt"
rem A10 (Antidote 10)
msiexec /qn /x {134E0741-C569-4E8C-A7FC-7F95B14CAAB1} /l*v "%LOG_PATH%\logDesAntidote10.txt"
msiexec /qn /x {134E0741-C569-4E8C-A7FC-7F95B14CAAB2} /l*v "%LOG_PATH%\logDesAntidote10_Module_Français.txt"
msiexec /qn /x {134E0741-C569-4E8C-A7FC-7F95B14CAAB3} /l*v "%LOG_PATH%\logDesAntidote10_English_Module.txt"
msiexec /qn /x {134E0741-C569-4E8C-A7FC-7F95B14CAAB4} /l*v "%LOG_PATH%\logDesAntidote10_Connectix.txt"
rem A11 (Antidote 11)
msiexec /qn /x {2643823D-D15F-4046-8388-401756A5C921} /l*v "%LOG_PATH%\logDesAntidote11.txt"
msiexec /qn /x {2643823D-D15F-4046-8388-401756A5C922} /l*v "%LOG_PATH%\logDesAntidote11_Module_Français.txt"
msiexec /qn /x {2643823D-D15F-4046-8388-401756A5C923} /l*v "%LOG_PATH%\logDesAntidote11_English_Module.txt"
msiexec /qn /x {2643823D-D15F-4046-8388-401756A5C924} /l*v "%LOG_PATH%\logDesAntidote11_Connectix.txt"
:OK_DESANCIENANTIDOTE

if exist "%ANTIDOTE_PATH%\Application\Bin64\Antidote.exe" goto OK_ANTIDOTE
if not exist "%REMOTE_PATH%\Antidote12.msi" goto OK_ANTIDOTE
msiexec /qn /i "%REMOTE_PATH%\Antidote12.msi" TRANSFORMS="%REMOTE_PATH%\ReseauAntidote.mst;%REMOTE_PATH%\Antidote12-Interface-fr.mst" /l*v "%LOG_PATH%\logInsAntidote12.txt"
:OK_ANTIDOTE

if exist "%ANTIDOTE_PATH%\LingFR\Bin64\libLingFR.dll" goto OK_MODULE_FR
if not exist "%REMOTE_PATH%\Antidote12-Module-francais.msi" goto OK_MODULE_FR
msiexec /qn /i "%REMOTE_PATH%\Antidote12-Module-francais.msi" TRANSFORMS="%REMOTE_PATH%\Antidote12-Module-francais-Interface-fr.mst" /l*v "%LOG_PATH%\logInsAntidote12_Module_Français.txt"
:OK_MODULE_FR

if exist "%ANTIDOTE_PATH%\LingEN\Bin64\libLingEN.dll" goto OK_MODULE_EN
if not exist "%REMOTE_PATH%\Antidote12-English-module.msi" goto OK_MODULE_EN
msiexec /qn /i "%REMOTE_PATH%\Antidote12-English-module.msi" TRANSFORMS="%REMOTE_PATH%\Antidote12-English-module-Interface-fr.mst" /l*v "%LOG_PATH%\logInsAntidote12_English_Module.txt"
:OK_MODULE_EN

if exist "%CONNECTIX_PATH%\Application\Bin64\Connectix.exe" goto OK_CONNECTIX
if not exist "%REMOTE_PATH%\Antidote-Connectix12.msi" goto OK_CONNECTIX
msiexec /qn /i "%REMOTE_PATH%\Antidote-Connectix12.msi" TRANSFORMS="%REMOTE_PATH%\ReseauConnectix.mst;%REMOTE_PATH%\Antidote-Connectix12-Interface-fr.mst" /l*v "%LOG_PATH%\logInsAntidote12_Connectix.txt"
:OK_CONNECTIX

Deployment in an Organization

Installing